Initial assumptions about coordinates

$Assumptions={r>0 ,rp>0,t>0,θ1>θ>0,z>0};

Definition of u

u[t_,r_,rp_,z_]:=ArcCosh[(1/(2r *rp))((r^2)+(rp^2)+(t^2)+(z^2))];

Tbar for the cone of periodicity θ1

Tbar[t_,r_,θ_,z_,rp_,thp_,zp_]=-(1/(2π θ1 r rp Sinh[u[t,r,rp,z]]))*((Sinh[2π u[t,r,rp,z]/θ1])/(Cosh[2π u[t,r,rp,z]/θ1]-Cos[2π (θ-thp)/θ1]));

Calculation of T_μν components, with nonzero separation along t (NOT renormalized)
Remove semicolons to view output

T00[t_,r_,θ_,θ1_]=-(1/2)D[Tbar[t,r,θ,z,rp,thp,zp],{t,2}]/.{rp->r,thp->θ,z->0};

Trr[t_,r_,θ_,θ1_]=(-(1/4)(D[D[Tbar[t,r,θ,z,rp,thp,zp],rp],r]-D[Tbar[t,r,θ,z,rp,thp,zp],{r,2}]))/.{rp->r,thp->θ,z->0};

Tpp[z_,r_,θ_,θ1_]=((1/(4r))D[Tbar[t,r,θ,z,rp,thp,zp],r]+(1/(4r^2))(D[Tbar[t,r,θ,z,rp,thp,zp],{θ,2}]-D[D[Tbar[t,r,θ,z,rp,thp,zp],θ],thp]))/.{rp->r,thp->θ,z->0};

Tzz[t_,r_,θ_,θ1_]=(1/2)(D[Tbar[t,r,θ,z,rp,thp,zp],{z,2}])/.{rp->r,thp->θ,z->0};

Verification that (t^4) T_μν, r->r t, are independent of t

D[(t^4)T00[t,r,x,y]/.r->r t,t]//FullSimplify

D[(t^4)Trr[t,r,x,y]/.r->r t,t]//FullSimplify

D[(t^4)Tpp[t,r,x,y]/.r->r t,t]//FullSimplify

D[(t^4)Tzz[t,r,x,y]/.r->r t,t]//FullSimplify

Energy density and pressure components, as functions of r/t (and renormalized here by subtracting divergent flat-space terms)
Remove semicolons to view output

rho[r_,θ1_]=(t^4)(T00[t,r t,θ,θ1]-(3/(2 (π^2) (t^4))));

Pr[r_,θ1_]=(t^4)(Trr[t,r t,θ,θ1]-(1/(2 (π^2) (t^4))));

Pp[r_,θ1_]=(t^4)(Tpp[t,r t,θ,θ1]-(1/(2 (π^2) (t^4))));

Pz[r_,θ1_]=(t^4)(Tzz[t,r t,θ,θ1]-(1/(2 (π^2) (t^4))));

Limits of quantities as θ1 goes to 0

Limit[rho[r,x]/.r->1,x->0]

Limit[Pr[r,x]/.r->1,x->0]

Limit[Pp[r,x]/.r->1,x->0]

Limit[Pz[r,x]/.r->1,x->0]

Calculation of no-cutoff case using series expansion

reT00[r_,θ1_]=FullSimplify[SeriesCoefficient[T00[t,r,θ,θ1],{t,0,0}]]

reTrr[r_,θ1_]=FullSimplify[SeriesCoefficient[Trr[t,r,θ,θ1],{t,0,0}]]

reTpp[r_,θ1_]=FullSimplify[SeriesCoefficient[Tpp[t,r,θ,θ1],{t,0,0}]]

reTzz[r_,θ1_]=FullSimplify[SeriesCoefficient[Tzz[t,r,θ,θ1],{t,0,0}]]

Plot style

myStyle=Partition[
Riffle[
Riffle[
ColorData[1,"ColorList"],ColorData[1,"ColorList"]]
,{Dashing[{}],Dashed}]
,2];

SetOptions[Plot,
Frame->True,
RotateLabel->True,
PlotStyle->myStyle];

SetDirectory[NotebookDirectory[]]

Plots

coneplot1=Plot[
Evaluate[1440(π^2)Flatten[Table[{rho[r,θ1],reT00[r,θ1]},{θ1,π*{1/4,1/Pi,1/2}}]]],{r,0,5},PlotRange->{-2000,16000},FrameLabel->{"r/t","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, 00])"}]

Export["coneplot1.png",coneplot1]

coneplot2=Plot[
Evaluate[1440(π^2)Flatten[Table[{Pr[r,θ1],reTrr[r,θ1]},{θ1,π*{1/4,1/Pi,1/2}}]]],{r,0.001,5},FrameLabel->{"r/t","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, rr])"},PlotRange->{0,2200}]

Export["coneplot2.png",coneplot2]

coneplot3=Plot[
Evaluate[1440(π^2)Flatten[Table[{Pp[r,θ1],reTpp[r,θ1]},{θ1,π*{1/4,1/Pi,1/2}}]]],{r,0.001,5},FrameLabel->{"r/t","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, pp])"},PlotRange->{-600,2300}]

Export["coneplot3.png",coneplot3]

coneplot4=Plot[
Evaluate[1440(π^2)Flatten[Table[{Pz[r,θ1],reTzz[r,θ1]},{θ1,π*{1/4,1/Pi,1/2}}]]],{r,0.001,5},PlotRange->{0,5500},FrameLabel->{"r/t","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, zz])"}]

Export["coneplot4.png",coneplot4]

coneangle1=Plot[
Evaluate[1440(π^2)Flatten[Table[{rho[r,θ1],reT00[r,θ1]},{r,{1}}]]],{θ1,0,4Pi},FrameLabel->{"θ1","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, 00])"},PlotRange->{-20,100}]

Export["coneangle1.png",coneangle1]

coneangle2=Plot[
Evaluate[1440(π^2)Flatten[Table[{Pr[r,θ1],reTrr[r,θ1]},{r,{1}}]]],{θ1,0,4Pi},FrameLabel->{"θ1","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, rr])"},PlotRange->{-5,100}]

Export["coneangle2.png",coneangle2]

coneangle3=Plot[
Evaluate[1440(π^2)Flatten[Table[{Pp[r,θ1],reTpp[r,θ1]},{r,{1}}]]],{θ1,0,4Pi},FrameLabel->{"θ1","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, pp])"},PlotRange->{-400,100}]

Export["coneangle3.png",coneangle3]

coneangle4=Plot[
Evaluate[1440(π^2)Flatten[Table[{Pz[r,θ1],reTzz[r,θ1]},{r,{1}}]]],{θ1,0,4Pi},FrameLabel->{"θ1","(1440 \!\(\*SuperscriptBox[\(π\), \(\(2\)\(\\ \)\)]\)(t^4))(Subscript[T, zz])"},PlotRange->{-20,100}]

Export["coneangle4.png",coneangle4]